Find the heart! VIC-20 game (BASIC) by BCO!

And now... The english language version of this pointless strip!

Scialve-a-tutti-belli-e-brutti!
Oggi vignetta/e (se consideriamo l'«english version») a tema visto che il post di oggi è dedicato ad un inutile (e probabilmente diseducativo) giochino scritto dal BCO durante uno dei suoi soliti attacchi d'insonnia per il BASIC del VIC-20 che simula il gioco delle tre carte sull'amichevole computer di casa Commodore!
Ecco l'inutile ma incriminante video dell'inutile ma ipnotico gioco:



...e questo è l'inutile codice:

new
10 a=65:b=83:c=65:ca=0:cb=2:cc=0:v1=7680:v2=38400:gosub 10000
20 print rnd(-time):print chr$(147)
30 gosub 5000
40 for t=1 to 1000:next
50 for n=1 to sn
60 gosub 4000
70 for t=1 to p*2:next
80 r=int(rnd(1)*3)+1
90 if r=1 then gosub 1000
100 if r=2 then gosub 2000
110 if r=3 then gosub 3000
120 next
130 gosub 4000
140 print "1 2 3"
150 input "wich one";i$
160 if i$<>"1" and i$<>"2" and i$<>"3" then goto 150
165 w=0
170 if i$="1" and a=83 then w=1
180 if i$="2" and b=83 then w=1
190 if i$="3" and c=83 then w=1
200 gosub 5000
210 if w=0 then print "you lose!"
220 if w=1 then print "you win!"
230 input "again (y/n)";r$
240 if r$="y" then run
250 if r$="n" then print "have a nice day!":end
260 goto 230
1000 s=a:a=b:b=s: s=ca:ca=cb:cb=s
1010 poke v2, 1:poke v2+1,  0:poke v2+2, 1:poke v2+3, 1:poke v2+4,  0
1015 poke v1,32:poke v1+1,102:poke v1+2,32:poke v1+3,32:poke v1+4,102
1020 for t=1 to p:next
1030 return
2000 s=b:b=c:c=s: s=cb:cb=cc:cc=s
2010 poke v2,  0:poke v2+1, 1:poke v2+2, 1:poke v2+3,  0:poke v2+4, 1
2015 poke v1,102:poke v1+1,32:poke v1+2,32:poke v1+3,102:poke v1+4,32
2020 for t=1 to p:next
2030 return
3000 s=a:a=c:c=s: s=ca:ca=cc:cc=s
3010 poke v2,  1:poke v2+1,  0:poke v2+2,  0:poke v2+3,  0:poke v2+4,  1
3020 poke v1, 32:poke v1+1,102:poke v1+2,102:poke v1+3,102:poke v1+4, 32
3030 for t=1 to int(p/3):next
3040 poke v2,  1:poke v2+1,  1:poke v2+2,  0:poke v2+3,  1:poke v2+4,  1
3050 poke v1, 32:poke v1+1, 32:poke v1+2,102:poke v1+3, 32:poke v1+4, 32
3060 for t=1 to int(p/3):next
3070 poke v2,  1:poke v2+1,  0:poke v2+2,  0:poke v2+3,  0:poke v2+4,  1
3080 poke v1, 32:poke v1+1,102:poke v1+2,102:poke v1+3,102:poke v1+4, 32
3090 for t=1 to int(p/3):next
3100 return
4000 poke v2,0:poke v2+1,1:poke v2+2,0:poke v2+3,1:poke v2+4,0
4010 poke v1,102:poke v1+1,32:poke v1+2,102:poke v1+3,32:poke v1+4,102
4020 return
5000 poke v2, ca:poke v2+1,  1:poke v2+2, cb:poke v2+3,  1:poke v2+4, cc
5010 poke v1,  a:poke v1+1, 32:poke v1+2,  b:poke v1+3, 32:poke v1+4,  c
5020 return
10000 print chr$(147)+"find the 'S'!"
10020 l=1:input "wich level (1-3)";l$
10030 if l$<>"1" and l$<>"2" and l$<>"3" then goto 10020
10040 sn=7:p=300
10050 if l$="1" then sn=7:p=300
10060 if l$="2" then sn=12:p=150
10070 if l$="3" then sn=17:p=75
10080 print "hit a key to start!"
10090 get a$:if a$<>"" then return
10100 goto 10090
run

..se a qualcuno va di ribatterlo sulla tastiera di un vero VIC-20!

E per finire in bellezza ecco tre inutili screenshots:

Potete trovare tutti i programmini che ho battuto (ma per un soffio perché erano avversari in gamba) per VIC-20 su questa pagina del sito (4)Seasons o sparsi allo stato brodo brado su questo medesimo blog.

Prima o poi farò anche un disco-raccolta con tutti i programmini, promesso (n.d.BCO)!

Il commento sonoro che sentite in sottofondo nel video è una versione pseudo-8-bit fatta-dal-BCO-con-quello-che-aveva-in-casa dell'arcinoto successo Money degli ABBA (che-alla-TATA-piacciono-assai).

Stay cheated!
(il bello è che il gioco non truffa anche se è di fatto BCO come programmatore è una truffa!)